;Czex3D_sel.mj
;3D methyl Cz-EXSY experiment, John et al., 2007
;two indirect 13C dimensions
;13C-enhancement by H-C NOE
;selective 13C excitation pulses for reduced 13C-sweepwidth in t2
;water suppression by 3-9-19 Watergate
;mixing time is d25

#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


;############# ASED parameters ##################
;in0 = 1/[2*SWH(13C)] (F1 spectral width)
;in10 = 1/[2*SWH(13Cmethyl)] (F2 spectral width)
;p1 = 90deg high power on 1H (f1, pl1)
;p3 = 90deg high power on 13C (f2, pl2)
;p13 = 90deg selective 13C on methyl (1.5m Q5)
;spnam13 = Q5
;spnam15 = Q5tr
;p16 >= 800u gradient pulse
;pcpd2 >80u 13C decoupler (pl12,f2)
;d4  <= 1.8m (C-H evolution on H)
;d14 <= 750u (C-H evolution on C) 
;d16 >= 100u (gradient recovery)
;d19 <= 2*DW (for 3-9-19)
;d23 >= 1.5m (echo for CSA/DD decoupling)

;############# fixed parameters, do not change ####
"p2=p1*2"
"p0=p1*4/3"
"p4=p3*2"
"d0=in0*0.5-p3*0.63-p2*0.5"
"d10=3u"
"d11=10m"		;delay for phase and buffer incrementation 
"d24=d23-p16-d16"
"d25=(d23*4+p2*2)*(cnst10+1)	;calculated mixing time
define delay d4a	;compensated d4 J-evolution delays
define delay d10c
define delay d19a
"d4a=500u"
"d10c=d10*2+p2"
"d19a=d19-p3"
"l10=cnst10"

aqseq 321

1 ze
  d25
2 d1  do:f2
  d11 pl1:f1
  d11 pl2:f2

;### NOE enhancement of Cz ###
5 (p0 ph0):f1
     5m
  lo to 5 times l11
  p16:gp1*0.8
    d16

;### Start of t1 on 13C ###
  (p3 ph5):f2
    d0
  (p2 ph0):f1
    d0			

;### Start of T1 mixing ### 
  (p3 ph12):f2			;flipping C coherence +/-z cancels
    d24 UNBLKGRAD 		;13C equilibrium magnetisation as T1 offset
  p16:gp1*0.5			;z-spoil
    d16				;H2O in +z
  (p2 ph20)			;decoupling of CSA/DD cross-correlated relaxation
    d23 ip20			;using MLEV expansion
15  d23 ip20			;H2O in -z
  (p2 ph20)
    d23 			;H2O in +z
    d23
  (p2 ph20)
    d23 ip20			;H2O in -z
  lo to 15 times l10
    d23 ip20			;H2O in -z
  (p2 ph20)
    d24				;H2O in +z
  p16:gp1*0.7			;z-spoil
    d16				

;### Start of t2 on 13C and methyl-selective transfer to 1H ###
  (p13:sp13 ph7):f2
    d14
    d10c
  (p4 ph0):f2
    d10
  (p2 ph0):f1
    d10
    d14
  (p13:sp15 ph1):f2

;### CH rephasing and watergate ###
  p16:gp1*0.6			;z-spoil
    d16

  (p1 ph0):f1
    d4a
  p16:gp1*0.4
    d16
  (p1*0.231 ph14):f1
    d19*2 
  (p1*0.692 ph14):f1
    d19*2 
  (p1*1.462 ph14):f1
    d19a
  (p4 ph0):f2
    d19a
  (p1*1.462 ph15):f1
    d19*2 
  (p1*0.692 ph15):f1
    d19*2 
  (p1*0.231 ph15):f1
  p16:gp1*0.4
    d16 pl12:f2
    d4a BLKGRAD

;### Start of data acquisition ###
  go=2 ph31 cpd2:f2	
    d11 do:f2 mc #0 to 2 
    F1PH(rd10 & ip5, id0) 
    F2PH(ip7, id10)

  exit
  
ph0= 0 
ph1= 1
ph2= 2
ph5= 0 2  		;(C) t1 excitation pulse, States phase
ph7= 0                  ;(C) t2 excitation pulse, States phase
ph12= 0 0 2 2  		;flips aternating to +/- Cz for mixing
ph14= {{0}*4}^2		;watergate phase
ph15= {{2}*4}^2		
ph20= 0
ph31= 0 2 2 0